だかひーwiki

TeraTermで自動ログインするマクロ

踏み台サーバ~リモートサーバまで自動ログイン

日本語で書いてる部分は自身の環境によって適宜修正してください。

;踏み台サーバの情報
hostname0 = 'IPアドレス または ホスト名'
username0 = 'ログインアカウント'
password0 = 'パスワード'

; 接続先のサーバー情報
hostname1 = 'IPアドレス または ホスト名'
username1 = 'ログインアカウント'
password1 = 'パスワード'

;踏み台サーバーへ接続
msg = hostname0
strconcat msg ':22 /ssh /auth=password /user='
strconcat msg username0
strconcat msg ' /passwd='
strconcat msg password0
connect msg

;「#」という文字がでるまで待つ
;サーバのプロンプトによって適宜変更する
prompt1 = '#'
wait prompt1

;踏み台サーバーから接続先サーバーにログイン
msg = ''
strconcat msg 'ssh '
strconcat msg username1
strconcat msg '@'
strconcat msg hostname1
sendln msg

; 「password」という文字が出たら改行(エンターと同じ意味)
prompt2 = "password"
wait prompt2
sendln password1

; TeraTermのウィンドウタイトルを変更しておく
settitle hostname1


; 自動ログ記録
logdir = 'ログを保存したいフォルダのフルパス'
; 例)C:¥Users¥hoge¥Desktop¥log\ など

logfile = logdir
;strconcat logfile username
;strconcat logfile '@'
strconcat logfile 'ファイルの先頭につける名前(ホスト名とか)'
getdate datetime '_%Y%m%d_%H%M%S'
strconcat logfile datetime
strconcat logfile '.log'
logopen logfile 0 1

トップ   編集 凍結 差分 バックアップ 添付 複製 名前変更 リロード   新規 一覧 単語検索 最終更新   ヘルプ   最終更新のRSS
Last-modified: 2014-01-29 (水) 12:05:48 (2115d)